import processing.opengl.*;

// Demonstrates sound-reactive particles using a custom class.
// MIDI controller 0 is used to control FFT damping speed.
// Note: Uses proMIDI 1.0.

import pitaru.sonia_v2_9.*; 
import SoniaHelper.*;
import promidi.*;

MidiIO midi;
float level,damperval;
SoniaHelper fft;

// variables for our sound-reactive particles
int num;
Particle part[];

void setup(){
  size(512,400, OPENGL);
  hint(ENABLE_OPENGL_4X_SMOOTH);
  
  initSound();
  initMIDI();
  
  // set up particles
  num=200;
  part=new Particle[num];
  for(int i=0; i<num; i++) part[i]=new Particle();
}

void draw() {
  background(0);

  getSound();

  // draw all our particles
  for(int i=0; i<num; i++) part[i].draw();
}


/////////////////////////////////////////////
// Sound-related methods

void getSound() {
  // get spectrum data from Sonia and use SoniaHelper to modify spectrum data.
  LiveInput.getSpectrum();  
  fft.update(LiveInput.spectrum);
}
  
void initSound() {
  // Start Sonia engine.
  Sonia.start(this); 

  // Start LiveInput and return 256 FFT frequency bands.
  LiveInput.start(256); 
  LiveInput.useEqualizer(true);

  // Initialize SoniaHelper
  // SoniaHelper(int _n, int _nbands,boolean doAvg)
  int spectrumLength=256;
  int numbands=8;
  
  fft=new SoniaHelper(spectrumLength,numbands,false);
  fft.setMaxLimits(50,500);
  
  // dampen sound input. 0.1 == 10% change per frame.
  damperval=0.1;
  fft.setDamper(damperval);  
}


/////////////////////////////////////////////
// MIDI-related methods

void controllerIn(Controller controller){
  // get controller number
  int num = controller.getNumber();
  
  // calculate value normalized to range [0..1]
  float val = (float)controller.getValue()/127;

  println(num+" "+val);

  // use controller 0 to control damping value for SoniaHelper
  if(num==0) {
    damperval=val;
    fft.setDamper(damperval);  
  } 
}

void initMIDI() {
  // set up MIDI input, catching any exception if thrown
  try {   
    midi = MidiIO.getInstance(this);
    int inputDeviceNumber=1;
    midi.openInput(inputDeviceNumber);
  }
  catch(Exception e) {
    println("MIDI not available.");
    println("Exception: "+e.toString()+"\n");
    midi=null;
  }
}
    

// class describing our sound-reactive particles
class Particle {
  int fftid;
  float x,y,yD,rad;
  
  // constructor for class Particle
  Particle() {
    // choose random FFT bin. 
    // Bin 0 is almost always empty, so don't use it.
    fftid=(int)random(fft.spectrum.length-1)+1;
    
    // set up random position and falling speed
    x=random(width);
    y=0;
    yD=random(1,3);
  }
  
  // update position and draw with size corresponding to the fft value
  void draw() {
    y=y+yD;
    if(y>height) y=0;    
    rad=5+fft.spectrum[fftid]*80;
    
    fill(0,255,255, 200);
    ellipse(x,y, rad,rad);
    ellipse(x,y, 10,10);
  }
}