// =========================================================================
// Markus Lerner
// http://www.markuslerner.com
// 2003-10-28
//
// Gesture
// =========================================================================

BImage bgImage;

int num = 100;
Vec2D mousePast[];
int pastNum = 40;
int waitCount = 0;
float radAngleY = 0;
float maxRotSpeed = 0.02;
float gCenterX, gCenterY;

PLine p[];

// button vars
int buttonNum;
int state = 0;
Button[] buttons;
BFont univers;

// setup ===================================================================
void setup() {
  size(600, 300);
  gCenterX = width/2;
  gCenterY = height/2;
  background(0,0,0);
  // smooth();
  noSmooth();
  framerate(30);
  ellipseMode(CENTER_DIAMETER);

  bgImage = loadImage("bg_ge.jpg");
  image(bgImage, 0, 0);

  mousePast = new Vec2D[pastNum];
  for(int i=0; i<pastNum; i++) mousePast[i] = new Vec2D();

  p = new PLine[num];
  int rgValue = int(255-random(40));
  for(int i=0; i<num; i++) p[i]= new PLine(0, random(-maxRotSpeed, maxRotSpeed), random(-maxRotSpeed, maxRotSpeed), 1, color(rgValue,rgValue,255), i);

  // create buttons
  buttonNum = 3;
  buttons=new Button[buttonNum];
  buttons[0]=new Button(20,275, 7,7, 0);
  buttons[1]=new Button(40,275, 7,7, 1);
  buttons[2]=new Button(60,275, 7,7, 2);
  for(int i=0; i<buttonNum; i++) buttons[i].setColor(255,255,255, 128,128,128);

  univers = loadFont("Univers55.vlw.gz");
}

// loop ====================================================================
void loop() {
  // draw background
  background(0,0,0);
  image(bgImage, 0, 0);
  color currentColor = color(0,50,200);

  // draw buttons
  for(int i=0; i<buttonNum; i++) buttons[i].draw();

  fill(255, 255, 255);
  textFont(univers, 15);
  text("MODE", 20, 265);

  // save past
  waitCount++;
  if(waitCount == 1) {
    for(int i=pastNum-1; i>0; i--) mousePast[i].set(mousePast[i-1]);
    mousePast[0].set(mouseX, mouseY);
    waitCount = 0;
  }
  //fill(255,0,0);
  //rect(0, 0, 100, 100);

  translate(gCenterX, gCenterY, 0);
  //radAngleY += 0.01;
  //rotateY(radAngleY);

  //rect(0, 0, 100, 100);

  //draw past
  for(int i=0; i<pastNum-1; i++) {
    float scale = 1-float(i)/float(pastNum);

    // color c = imagePixels[int(mousePast[i].x)][int(mousePast[i].y)];
    color c = currentColor;
    fill(red(c), green(c), blue(c), scale*100);
    stroke(red(c), green(c), blue(c), scale*100);

    push();
    translate(-gCenterX, -gCenterY, 0);
    if(i != 0) {
      line(mousePast[i].x, mousePast[i].y, mousePast[i-1].x, mousePast[i-1].y);
    }
    pop();
  }
  for(int i=0; i<num; i++) p[i].loop();
}

// mouse methods ===========================================================
void mousePressed() {
  for(int i=0; i<buttonNum; i++) buttons[i].check(mouseX,mouseY);
  gCenterX = mouseX;
  gCenterY = mouseY;
}
void mouseMoved() {
  if(state == 1) {
    gCenterX = mouseX;
    gCenterY = mouseY;
  }
}

// key methods ===========================================================
void keyReleased() {
  if(key == ' ') {
    state ++;
    if(state >= buttonNum) {
      state = 0;
    }
  }
}

// PLine class =============================================================
class PLine {
  float rotSpeedX, rotSpeedY, rotSpeedZ, size;
  float PangleX = 0;
  float PangleY = 0;
  float PangleZ = 0;
  int id;
  color c;

  PLine(float _rotSpeedX, float _rotSpeedY, float _rotSpeedZ, float _size, color _c, int _id) {
    rotSpeedX = _rotSpeedX;
    rotSpeedY = _rotSpeedY;
    rotSpeedZ = _rotSpeedZ;
    size = _size;
    id = _id;
    c = _c;
  }
  void loop(){
    PangleX += rotSpeedX;
    PangleY += rotSpeedY;
    PangleZ += rotSpeedZ;
    drawPast();
  }
  void drawPast() {
    for(int i=0; i<pastNum-1; i++) {
      float scale = 1-float(i)/float(pastNum);

      // color c = imagePixels[int(mousePast[i].x)][int(mousePast[i].y)];
      // color c = get(int(mousePast[i].x), int(mousePast[i].y));
      // color c = currentColor;
      stroke(red(c), green(c), blue(c), scale*100);

      push();
      rotateX(PangleX);
      rotateY(PangleY);
      rotateZ(PangleZ);
		if(state == 2) {
      translate(-gCenterX, -gCenterY, scale*100);
		}
		else {
		translate(-gCenterX, -gCenterY, 0);
		}

      if(i != 0) {
        line(mousePast[i].x, mousePast[i].y, mousePast[i-1].x, mousePast[i-1].y);
      }
      pop();
    }
  }
}

// General class for buttons ===============================================
class Button {
  int x,y,w,h;
  int id;
  color activeCol,inactiveCol;

  Button(int _x,int _y,int _w,int _h, int _id) {
    x=_x;
    y=_y;
    w=_w;
    h=_h;
	id=_id;
  }

  void setColor(int r1,int g1,int b1, int r2,int g2,int b2) {
    activeCol=color(r1,g1,b1);
    inactiveCol=color(r2,g2,b2);
  }

  void draw() {
		noFill();
		stroke(activeCol);
		line(x,y, x+w,y);
		line(x+w,y, x+w,y+h);
		line(x+w,y+h, x,y+h);
		line(x,y+h, x,y);

	 if(state == id) {
	  fill(activeCol);
      rect(x,y,w,h);
	}
  }

  void check(int mx,int my) {
    if(mx>=x && mx<=x+w && my>=y && my<=my+h) state = id;
  }
}

// General vector class for 2D vectors =====================================
class Vec2D {
  float x,y;

  // Constructor with no parameters
  Vec2D() {
    x=0;
    y=0;
  }

  Vec2D(float _x,float _y) {
    x=_x;
    y=_y;
  }

  Vec2D(Vec2D v) {
    x=v.x;
    y=v.y;
  }

  void set(float _x,float _y) {
    x=_x;
    y=_y;
  }

  void set(Vec2D v) {
    x=v.x;
    y=v.y;
  }

  void add(float _x,float _y) {
    x+=_x;
    y+=_y;
  }

  void add(Vec2D v) {
    x+=v.x;
    y+=v.y;
  }

  void sub(float _x,float _y) {
    x-=_x;
    y-=_y;
  }

  void sub(Vec2D v) {
    x-=v.x;
    y-=v.y;
  }

  void mult(float m) {
    x*=m;
    y*=m;
  }

  void div(float m) {
    x/=m;
    y/=m;
  }

  float length() {
    return sqrt(x*x+y*y);
  }

  float angle() {
    return atan2(y,x);
  }

  void normalise() {
    float l=length();
    if(l!=0) {
      x/=l;
      y/=l;
    }
  }

  Vec2D tangent() {
    return new Vec2D(-y,x);
  }

  void rotate(float val) {
    // Due to float not being precise enough, double is used for the calculations
    double cosval=Math.cos(val);
    double sinval=Math.sin(val);
    double tmpx=x*cosval - y*sinval;
    double tmpy=x*sinval + y*cosval;

    x=(float)tmpx;
    y=(float)tmpy;
  }
}