Palette pal;

void setup () {
  size(300,300);
  ellipseMode(CENTER_DIAMETER);
  
  pal=new Palette();
  pal.add(255,0,0);
  pal.add(255,0,100);
  pal.add(255,0,100, 128); // with alpha
  pal.add(255,100,0);
  pal.add(color(100,200,0), 6); // several of the same color
  pal.addRange(10, 255,100,0, 255,220,0);
  pal.addRange(10, 0,100,255,100, 0,0,50,200); // with alpha
  
  for(int i=0; i<70; i++) pal.add(random(255),random(255),random(255));
}

void loop() {
  background(255);

  noStroke();
  for(int i=0; i<pal.num; i++) {
    fill(pal.c[i]);
    rect((i%10)*30,(i/10)*30, 29,29);
  }  
    
}

// Color palette utility class
// By watz - processing.unlekker.net

class Palette {
  int num,alloc;
  color c[];
  
  public Palette() {
    num=0;
    alloc=100;
    c=new color[alloc];
  }
  
  // add a single color entry
  public void add(color col) {
  
    // grow array size if necessary
    if(num==alloc) {
      alloc*=2;
      color tmp[]=new color[alloc];
      for(int i=0; i<num; i++) tmp[i]=c[i];
      c=tmp;
    }
    
    c[num]=col;
    num++;
  }

  // add a number of entries of the same color
  public void add(color col,int numcol) {
    for(int i=0; i<numcol; i++) add(col);
  }
  
  public void add(float r,float g,float b) {
    add(color(r,g,b));  
  }

  public void add(float r,float g,float b,float a) {
    add(color(r,g,b,a));  
  }
  
  // add interpolated range of colors
  public void addRange(float numrange,
    float r,float g,float b,float r2,float g2,float b2) {
    
    float fract;

    r2=(r2-r);
    g2=(g2-g);
    b2=(b2-b);
    for(float i=0; i<numrange; i++) {
      fract=i/(numrange-1);
      add(color(r + r2 * fract, g + g2 * fract, b + b2 * fract));
    }    
  }
  
  // add interpolated range of colors with alpha
  public void addRange(float numrange,
    float r,float g,float b,float a,
    float r2,float g2,float b2,float a2) {
    
    float fract;

    r2=(r2-r);
    g2=(g2-g);
    b2=(b2-b);
    a2=a2-a;
    for(float i=0; i<numrange; i++) {
      fract=i/(numrange-1);
      add(color(r + r2 * fract, g + g2 * fract, b + b2 * fract, a+a2*fract));
    }    
  }

  public color getRandom() {
    return c[(int)random(num)];
  }
}