// UdK Computational design
// Marius Watz 2003
// http://www.evolutionzone.com/udk/
//
// UDK03_03_mouse
//
// Use vectors to store mouse positions.

Vec2D v[];
int num=100;

void setup() {
  size(400,400);

  ellipseMode(CENTER_DIAMETER);

  v=new Vec2D[num];
  for(int i=0; i<num; i++) v[i]=new Vec2D();
  
  
}

void loop() {
  background(200,200,200);
  
  noStroke();
  fill(255,0,0);
  stroke(255,0,0);
  for(int i=0; i<num-1; i++) line(v[i].x,v[i].y, v[i+1].x,v[i+1].y);  
}

void mouseMoved() {
  for(int i=num-1; i>0; i--) v[i].set(v[i-1]);
  v[0].set(mouseX,mouseY);  
}


// General vector class for 2D vectors
class Vec2D {
  float x,y;

// Constructor with no parameters
  Vec2D() {
    x=0;
    y=0;
  }
  
  Vec2D(float _x,float _y) {
    x=_x;
    y=_y;
  }

  Vec2D(Vec2D v) {
    x=v.x;
    y=v.y;
  }

  void set(float _x,float _y) {
    x=_x;
    y=_y;
  }

  void set(Vec2D v) {
    x=v.x;
    y=v.y;
  }

  void add(float _x,float _y) {
    x+=_x;
    y+=_y;
  }

  void add(Vec2D v) {
    x+=v.x;
    y+=v.y;
  }

  void sub(float _x,float _y) {
    x-=_x;
    y-=_y;
  }

  void sub(Vec2D v) {
    x-=v.x;
    y-=v.y;
  }

  void mult(float m) {
    x*=m;
    y*=m;
  }

  void div(float m) {
    x/=m;
    y/=m;
  }

  float length() {
    return sqrt(x*x+y*y);
  }

  float angle() {
    return atan2(y,x);
  }

  void normalise() {
    float l=length();
    if(l!=0) {
      x/=l;
      y/=l;
    }
  }

  Vec2D tangent() {
    return new Vec2D(-y,x);
  }

  void rotate(float val) {
    // Due to float not being precise enough, double is used for the calculations
    double cosval=Math.cos(val);
    double sinval=Math.sin(val);
    double tmpx=x*cosval - y*sinval;
    double tmpy=x*sinval + y*cosval;

    x=(float)tmpx;
    y=(float)tmpy;
  }
}