Option Explicit
'Script written by Marius Watz
'Script version 14. februar 2008 10:56:41

Call Clear
Call Main()

Sub Main()
	Call rhino.enableRedraw(False)

	Dim i,j
	For i=0 To 10
		For j=0 To 10
			Call rndCube(i*15,j*15)
		Next
	Next

	Call rhino.enableRedraw(True)
End Sub

Function rndVec(range)
	rndVec=Array(Rnd*range-range/2,Rnd*range-range/2,Rnd*range-range/2)
End Function

Function rndCube(xpos,ypos) 

	Dim pt(8)
	Dim c1,c2

	Dim rad
	rad=5
	pt(0)=Array(-rad,-rad,rad)
	pt(1)=Array(rad,-rad,rad)
	pt(2)=Array(rad,rad,rad)
	pt(3)=Array(-rad,rad,rad)

	pt(4)=Array(-rad,-rad,-rad)
	pt(5)=Array(rad,-rad,-rad)
	pt(6)=Array(rad,rad,-rad)
	pt(7)=Array(-rad,rad,-rad)	

	Dim i,rndv,rndH
	rndH=Rnd*rad*2
	For i=0 To 3
		rndv=rndVec(4)
		rndv(2)=rndv(2)+rndH
		pt(i)=Rhino.VectorAdd(pt(i),rndv)
	Next

	For i=0 To 7
		pt(i)=Rhino.VectorAdd(pt(i),Array(xpos,ypos,0))
	Next

	Dim ln(8)
	For i=0 To 3
		ln(i)=Rhino.AddLine(pt(i),pt((i+1) Mod 4))
		ln(i+4)=Rhino.AddLine(pt(i+4),pt(((i+1) Mod 4)+4))
	Next

	Dim srf(6)
	For i=0 To 3
		srf(i)=Rhino.AddEdgeSrf(Array(ln(i),ln(i+4)))
	Next

	ln(0)=Rhino.AddLine(pt(1),pt(0))
	srf(4)=Rhino.AddEdgeSrf(Array(ln(0),ln(2)))
	srf(5)=Rhino.AddEdgeSrf(Array(ln(6),ln(4)))

	For i=0 To UBound(ln)-1
		Rhino.DeleteObject ln(i)
	Next

End Function

Sub Clear
	Rhino.Command "SelAll "
	Rhino.Command "Delete "
End Sub

MIT IAP RhinoScript workshop – Danzer Variations

While looking for RhinoScript resources for the Digital Architecture workshop at AHO I found a recent posting of the final projects from a RhinoScript workshop at MIT IAP. It features some very nice-looking work, including the Danzer tile forms shown above. It also provides the source code for most of the experiments, well worth checking out.

The resource page for a previous MIT workshop is still up, it has more scripts and some useful links: Computational Design Solutions Part 1.

Be sure to look at the page I have prepared with links related to computational architecture. Code will be uploaded to:
http://workshop.evolutionzone.com/workshops/080211_aho.

• Basic Processing syntax
• Simple animation
• Control structures: If / else, loops, keyPressed(), mousePressed()
• Transformations: translate(), scale(), rotate()
• Complex drawing: beginShape(), endShape()
• Data structures: Arrays, classes
• Polygon mesh generation
• Output: PDF, STL, DXF

• RhinoScript
• p5Sunflow, a radiosity rendering library for Processing

Rhinoscript sketch, extruding a revolution surface along random curves. Good cheesy fun.

I had a chance to see a bit more of the impressive tool Rhino 4 during the Generator.x 2.0 workshop, and so I thought I’d have a go at making a simple sketch in Rhinoscript. As it turns out, the fact that Rhinoscript is based on VBScript makes coding feel horrible at first. Seriously, who would want to use syntax like that? It might be easy for beginners to pick up, but it quickly gets painful once you’re dealing with complex API calls and 100+ lines of code.

Nevertheless, frustration soon gives way to amazement at the built-in Rhino library and its vast array of heavy-duty functions for creating and manipulating curves, meshes and NURBS surfaces. In comparison, mesh generation in Processing is enough to give anyone a headache, and I seriously doubt anyone would even attempt to implement NURBS. Even Boolean mesh operations is a staggering task, with no good Java libraries readily available.

While Rhinoscript is firmly a non-realtime tool, its power for pure geometry is amazing. I would definitely use Rhino as a creative tool for digital fabrication projects, where animation is not the goal. There are some excellent RhinoScript resources online, for starters look at RhinoScript 101 and David Rutten’s tutorial. I would also definitely recommend using the Monkey Script editor instead of the built-in editor, it’s more powerful and has a very useful documentation feature.

The script below gives a basic idea of the Rhino syntax, and while it is a basic sketch suffering from 3D clichées, it shows the power and versatility of Rhinoscript. I just wish it wasn’t Visual Basic.

'RandRail.rvb
'Marius Watz, http://workshop.evolutionzone.com

Option Explicit

Sub Main
	Dim doRender : doRender=1
	Dim num : num=100
	Dim pt, curve(100)

	Call rhino.enableRedraw(False)
	Rhino.Print "--------------------------"

	' delete any existing objects
	Dim oldScene:oldScene=Rhino.AllObjects()
	If isArray(oldScene) Then
		Rhino.DeleteObjects Rhino.AllObjects()
		Rhino.DeleteObjects Rhino.LightObjects()
	End If

	' Set up scene
	Dim light
	light=Rhino.AddPointLight (Array(0,-200,0))
	light=Rhino.AddPointLight (Array(-100,-100,0))

	Rhino.RenderColor 1, RGB(50,50,50)
	Rhino.RenderResolution Array(1200,900)
	Rhino.RenderAntialias 2

	' Create random curves
	Dim cp(3),mult, i
	For i=0 To num
		mult=random(0.75,1.25)
		cp(0)=Array(0,0,0)
		If Rnd>0.5 Then
			cp(1)=Array(0,random(30,50),0)
		Else
			cp(1)=Array(0,random(-30,20),0)
		End If
		If Rnd>0.5 Then
			cp(2)=Array(random(-50,50)*mult,random(30,50),random(-50,50)*mult)
		Else
			cp(2)=Array(random(-50,50)*mult,random(-30,20),random(-50,50)*mult)
		End If
		cp(3)=Array(random(-50,50)*mult,random(-50,50),random(-50,50)*mult)
		curve(i)=Rhino.AddCurve(cp)
		'		Rhino.AddSphere cp(2), dblRadius
	Next

	' Create random rounded profile
	Dim numRot : numRot=Int(random(7,18))
	Dim j, rndCurve(10),profPt(),deg,offs
	ReDim profPt(numRot)

	For j=0 To Ubound(rndCurve)
		For i=0 To numRot
			deg=(2*Rhino.Pi/numRot)*i
			offs=random(5,7)*0.2
			If i Mod 2=0 Then
				offs=random(7,12)*0.2
			End If

			profPt(i)=Array(Cos(deg)*offs, 0 ,Sin(deg)*offs)
		Next
		rndCurve(j)=Rhino.AddCurve(profPt)
	Next

	' Create random RailRefSrf and ExtrudeCurve surfaces
	Dim railAxis(1)
	railAxis(0)=Array(0,0,0)
	railAxis(1)=Array(0,1,0)

	Dim srf,profCurve
	For i=0 To num
		profCurve=rndCurve(Int(random(0,Ubound(rndCurve))))
		srf=Rhino.AddRailRevSrf(curve(i),profCurve,railAxis)
		applyRndMaterial(srf)
		'		srf=Rhino.ExtrudeCurve(profCurve,curve(i))
		'		applyRndMaterial(srf)
	Next

	If doRender=1 Then
		renderView()
	End If

	Call rhino.enableRedraw(True)

End Sub

' Set random materials
Function applyRndMaterial(obj)
	Dim prob,col,material

	material=Rhino.AddMaterialToObject (obj)

	' Coloring: Pink, Orange
	prob=random(0,100)
	If prob<30 Then
		Rhino.MaterialColor material, RGB(255, 0, Int(random(100,150)))
	ElseIf prob<90 Then
		Rhino.MaterialColor material, RGB(255, Int(random(100,254)),0)
	Else
		Rhino.MaterialColor material, RGB(255, 255, 255)
	End If
End Function

Function random(min,max)
	random=Rnd*(max-min)+min
End Function

' Render current viewport
Function renderView()
	Dim view,filename

	view = Rhino.CurrentView
	Rhino.Command "_-Render"
	filename=getRenderFileName("RandRail")
	Dim cmd : cmd="_-SaveRenderWindowAs " & Chr(34) & filename & Chr(34)
	Rhino.Command cmd
End Function

' Get auto-incremented filename
Function getRenderFileName(scriptName)
	Dim index,done, doc, file, temp,imgNum

	done=-1
	index=0
	Do While done=-1
		doc=Rhino.WorkingFolder & "\" & scriptName & padStr(scriptName,index) & ".png"
		file=Rhino.FindFile(doc)
		If IsNull(file)=True Then
			done=1
		Else
			index=index+1
		End If
	Loop

	getRenderFileName=doc
End Function

Function padStr(prefix,val)
	Dim l : l=Len(val)
	If l<1 Then
		padStr="000" & val
	ElseIf l<2 Then
		padStr="00" & val
	ElseIf l<3 Then
		padStr="0" & val
	Else
		padStr="" & val
	End If
End Function	

Main